Arduino

Daten in Reih und Glied – Arrays

Du legst viele Werte unter einem Namen ab und arbeitest sie der Reihe nach ab.

Viele Werte, ein Name

Ein Array ist eine geordnete Sammlung von Elementen, die alle denselben Datentyp haben. Statt zwanzig Variablen mit zwanzig Namen anzulegen, nimmst du ein Array mit einem Namen und sprichst die einzelnen Elemente über ihre Position an – den sogenannten Index.

Ein Schrank mit drei Schubladen ersteDrei[0] bis ersteDrei[2] mit den Werten 4, 8 und 15; die Schublade ersteDrei[1] ist herausgezogen

Wichtig: Der Index beginnt bei 0, nicht bei 1. Ein Array mit 6 Elementen hat also die Indizes 0 bis 5. Greifst du daneben, liest oder überschreibst du fremden Speicher – der PicoBoy stürzt dann ab oder zeigt Unsinn an, ohne dass der Compiler sich beschwert.

In C++ deklarierst du ein Array mit Datentyp, Name und Größe. Die Größe steht in eckigen Klammern und lässt sich später nicht mehr ändern:

int punkte[10];                // 10 ganze Zahlen, Indizes 0 bis 9
int ersteDrei[] = {4, 8, 15};  // mit Werten gefüllt, Größe ergibt sich daraus

punkte[0] = 42;                // dem ersten Element den Wert 42 zuweisen
int x = ersteDrei[2];          // das dritte Element auslesen, x ist danach 15

Arrays sind nützlich, um größere Mengen von Daten zu speichern und zu verarbeiten – besonders in Verbindung mit Schleifen. Die Schleifenvariable dient dann als Index, und du kommst mit wenigen Zeilen durch alle Elemente, statt den Code für jedes Element zu wiederholen.

Ein Liedtext Wort für Wort

Hier liegen sechs Texte in einem Array. Die Schleife zeigt sie nacheinander an und nutzt i gleich doppelt: als Index und für die Höhe der Zeile.

#include <U8g2lib.h>
#include <SPI.h>

U8G2_SH1106_128X64_NONAME_F_4W_HW_SPI u8g2(U8G2_R0, 10, 8, 9);

void setup(void) {
  // "const char*" ist der Datentyp für einen festen Text
  const char* words[] = {"Wir fahr'n", "fahr'n", "fahr'n",
                         "auf", "der", "Autobahn"};
  u8g2.begin();
  u8g2.setFont(u8g2_font_smart_patrol_nbp_tr);
  for (int i = 0; i < 6; i++) {                // sechs Texte: Indizes 0 bis 5
    u8g2.clearBuffer();
    u8g2.drawStr(0, (i * 10) + 10, words[i]);  // jede Zeile 10 Pixel tiefer
    u8g2.sendBuffer();
    delay(500);
  }
}

void loop() {}

Zweidimensionale Arrays

Ein Array kann auch mehrere Dimensionen haben. Dann brauchst du zwei Indizes, um ein Element anzusprechen – praktisch für alles, was ein Raster ist: ein Spielfeld, ein Labyrinth, ein Bild.

Das folgende Beispiel legt ein Spielfeld aus 10 × 5 Feldern an. Jedes Feld merkt sich eine Zahl: 0 für leer, 1 für einen gefüllten, 2 für einen leeren Spielstein. Erst werden alle Felder auf 0 gesetzt, dann ein paar Steine platziert, und am Ende zeichnen zwei geschachtelte Schleifen das Feld.

#include <U8g2lib.h>
#include <SPI.h>

U8G2_SH1106_128X64_NONAME_F_4W_HW_SPI u8g2(U8G2_R0, 10, 8, 9);

void setup(void) {
  int spielfeld[10][5];  // 10 Spalten, 5 Zeilen - zusammen 50 Felder

  for (int xCoord = 0; xCoord < 10; xCoord++) {  // alle Felder durchlaufen
    for (int yCoord = 0; yCoord < 5; yCoord++) {
      spielfeld[xCoord][yCoord] = 0;             // und auf 0 (= leer) setzen
    }
  }

  spielfeld[3][0] = 1;  // einzelne Felder belegen
  spielfeld[4][0] = 1;
  spielfeld[5][0] = 2;
  spielfeld[6][0] = 2;
  spielfeld[4][1] = 2;
  spielfeld[5][1] = 1;

  u8g2.begin();
  u8g2.setDisplayRotation(U8G2_R2);  // Anzeige um 180 Grad drehen
  u8g2.clearBuffer();
  u8g2.drawFrame(0, 0, 101, 51);     // Rahmen: 10*10+1 auf 5*10+1 Pixel

  for (int xCoord = 0; xCoord < 10; xCoord++) {
    for (int yCoord = 0; yCoord < 5; yCoord++) {
      if (spielfeld[xCoord][yCoord] == 1) {  // 1: gefüllter Stein
        u8g2.drawDisc((xCoord * 10) + 5, (yCoord * 10) + 5, 4);
      }
      if (spielfeld[xCoord][yCoord] == 2) {  // 2: leerer Stein
        u8g2.drawCircle((xCoord * 10) + 5, (yCoord * 10) + 5, 4);
      }
    }
  }
  u8g2.sendBuffer();
}

void loop() {}

Anmerkungen

  • Dass ein Feld 10 Pixel breit ist, taucht im Quelltext mehrfach auf (* 10 und + 5). Das Rechnen mit dem Index ist der Kern des Ganzen: Aus der Position im Array wird die Position auf dem Display.
  • Dieses Muster – ein Array als Spielfeld, Schleifen zum Zeichnen – steckt auch hinter dem Snake-Beispiel am Ende des Tutorials.
  • Warum werden zuerst alle Felder auf 0 gesetzt? Ein Array, das innerhalb einer Funktion deklariert wird, hat keinen festen Anfangsinhalt. Darin steht, was gerade im Speicher lag. Ohne die erste Schleife könnten also Steine auftauchen, die niemand gesetzt hat. Globale Arrays sind dagegen von Anfang an mit 0 gefüllt.
  • Hier ist immer der erste Index die Spalte und der zweite die Zeile. Das Feld unten rechts ist spielfeld[9][4]. Vertauschst du die Indizes, greifst du neben das Array.
  • setDisplayRotation() zeigt, dass sich die Drehung auch im laufenden Programm ändern lässt. Das Bild steht dadurch auf dem Kopf, und das Spielfeld liegt rechts unten. Nimmst du die Zeile heraus, beginnt es links oben.

Übung

Erweitere das Beispiel so, dass sich ein Spielstein mit dem Joystick über das Feld bewegen lässt. Tipp: Merke dir die Position des Steins in zwei Variablen, setze bei jeder Bewegung das alte Feld auf 0 und das neue auf 1.

Dafür ändert sich der Aufbau des Programms: spielfeld und die beiden Positionsvariablen wandern ganz nach oben, damit setup() und loop() sie gemeinsam nutzen können. Das Zeichnen wandert nach loop(), mit clearBuffer() davor und sendBuffer() dahinter. Ein delay(150) am Ende verhindert, dass der Stein bei einem Druck mehrere Felder springt. Achte auch auf den Rand: Die Spalte muss zwischen 0 und 9 bleiben, die Zeile zwischen 0 und 4.